lp03.gms : Many free variables and restart

Description

```In this test we check how a solver behaves when there are many
free variables and if it restarts from this optimal basis.
```

Small Model of Type : LP

Category : GAMS Test library

Main file : lp03.gms

``````\$title Many free variables and restart (LP03,SEQ=68)

\$ontext
In this test we check how a solver behaves when there are many
free variables and if it restarts from this optimal basis.
\$offtext

\$if not set MTYPE         \$set MTYPE lp
\$if not set DEMOSIZE      \$set DEMOSIZE   0
\$if not set GLOBALSIZE    \$set GLOBALSIZE 0
\$if not set SKIPITER      \$set SKIPITER   0
\$if not %DEMOSIZE% == 0   \$set DEMOSIZE   1
\$if not %GLOBALSIZE% == 0 \$set GLOBALSIZE 1

\$                                 set KK  20
\$if %DEMOSIZE%%GLOBALSIZE% == 11 \$set KK  3

Sets
i   canning plants   / seattle, san-diego /
j   markets          / new-york, chicago, topeka /
k                    / 1*%KK% /;

Parameters

a(i)  capacity of plant i in cases
/    seattle     350
san-diego   600  /

b(j)  demand at market j in cases
/    new-york    325
chicago     300
topeka      275  / ;

Table d(i,j)  distance in thousands of miles
new-york       chicago      topeka
seattle          2.5           1.7          1.8
san-diego        3.5           2.8          1.4  ;

Scalar f  freight in dollars per case per thousand miles  /90/ ;

Parameter c(i,j)  transport cost in thousands of dollars per case ;

c(i,j) = f * d(i,j) / 1000 ;

Variables
xx(k)   free variables
x(i,j)  shipment quantities in cases
z       total transportation costs in thousands of dollars ;

Positive Variable x ;

Equations
cost        define objective function
supply(i)   observe supply limit at plant i
demand(j)   satisfy demand at market j
stuff       silly equation;

cost ..        z  =e=  sum((i,j), c(i,j)*x(i,j));

supply(i) ..   sum(j, x(i,j))  =l=  a(i) ;

demand(j) ..   sum(i, x(i,j))  =g=  b(j) ;

stuff.. sum(k, xx(k)) =e= 0;

Model lp03 /all/ ;

option limcol=0,limrow=0;

Solve lp03 using %MTYPE% minimizing z ;
abort\$( lp03.solvestat <> %solvestat.NormalCompletion% or lp03.modelstat <> %modelstat.Optimal%) 'wrong status codes';
abort\$( sum(k, mapval(xx.m(k))=mapval(eps)) <> (card(k)-1)) 'wrong EPS';

Solve lp03 using %MTYPE% minimizing z ;
abort\$( lp03.solvestat <> %solvestat.NormalCompletion% or lp03.modelstat <> %modelstat.Optimal%) 'wrong status codes';
abort\$( sum(k, mapval(xx.m(k))=mapval(eps)) <> (card(k)-1)) 'wrong EPS';
\$if %SKIPITER% == 0 abort\$( lp03.iterusd > 0) 'too many iters';
``````
GAMS Development Corp.
GAMS Software GmbH

General Information and Sales
U.S. (+1) 202 342-0180
Europe: (+49) 221 949-9170